added some stuff

moduler/programs/neomd/default.nix

@@ -0,0 +1,50 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}:
+let
+  cfg = config.neomd;
+
+  neomdPackage = pkgs.buildGoModule {
+    pname = "neomd";
+    version = "unstable-2026-04-06";
+
+    src = pkgs.fetchFromGitHub {
+      owner = "ssp-data";
+      repo = "neomd";
+      rev = "671a9dd66bb367e21be7777a6765635a99b7ab09";
+      hash = "sha256-9IVrp9GTwr5aFsBy7lPPRXYCaeYTkOuM+VEdK7Tf2+o=";
+    };
+
+    vendorHash = "sha256-cG5x23qA+AN5zwEjdx8uDBk9JjNpn/afzI0/aAJjqAU=";
+    subPackages = [ "cmd/neomd" ];
+    ldflags = [
+      "-s"
+      "-w"
+    ];
+
+    meta = {
+      description = "Terminal email client for markdown and Neovim workflows";
+      homepage = "https://github.com/ssp-data/neomd";
+      license = lib.licenses.mit;
+      mainProgram = "neomd";
+    };
+  };
+in
+{
+  options.neomd = {
+    enable = lib.mkEnableOption "neomd terminal email client";
+
+    package = lib.mkOption {
+      type = lib.types.package;
+      default = neomdPackage;
+      description = "Package to install when neomd is enabled.";
+    };
+  };
+
+  config = lib.mkIf cfg.enable {
+    environment.systemPackages = [ cfg.package ];
+  };
+}